Need to set audible alarm for being plugged in but not charging.

Hi, there are many battery monitors out there that can alert you when your battery reaches a threshold for example.

Here's one that generates an audible and visual notification when power is applied or disconnected.


Bit of a weird name, but I've just tried it as you can see- connecting and disconnecting power.
BatteryDeley: Low laptop battery alert - Scripts and Functions - AutoHotkey Community

Just run the exe file from the zip.

As the Autohotkey source code is provided, you can even modify it yourself.

Rt click tray icon, Settings- lots of things you can change. Also looks as if it can generate alerts at different charge levels, which Windows also provides to some extent:
How to Set Low Battery Warnings on Your Windows 10 Laptop - dummies

Umm, yeah.


Thank you very much for your reply.


I showed the screenshots about connection and disconnection.

I only found it for you - uniquely, as the source code is available, you can customise it in addition to the various parameters you can set. I don't use it myself so can comment no further. Good luck with your search.

squiptryx said:

Note, a power setting that darkens the screen when the laptop is not charging would work as well.

I use a vbs script to alter the colour of my TitleBars when AC power is not present.
- The script detects the presence or absence of mains power not whether or not battery charging is taking place.
- I start it with Task scheduler at user login and it runs in the background until it detects a power change.
- My attitude to where to store scripts is explained in set up Tools folder - TenForums
- I have had to set a Windows defender exclusion for the folder my script is in because WD has started to report a false positive that it is a trojan [the fact that it is false is made clear by reading the script in Notepad].
- I find that this TitleBar change is sufficient. Whilst subtle enough to avoid annoying me if I am on battery power deliberately, it is visible enough to ensure that I am aware of the change [in case it was inadvertent]. It also reverts to the original colour when power is restored.

Mains power connected


Battery power in use - mains power disconnected



Here are the script & the Task scheduler task definition for launching it.BatteryDetector.zip
and here is the script in text form

Code:

' This script changes the active window TitleBar colour when a change of power source [AC/DC] is detected
' - I find this to be a nice subtle indicator that is not easily missed yet does not distract me from what I'm doing.
' - Settings, Personalisation, Colours, Accent colour does not reflect these changes when they are done directly on the Registry value but the changes do take effect

' This script is launched at user logon by a TS Task

' This script was based on code originally posted by 'b w' on 17th March 2010 at
' windows 7 - Is there a way to execute a program on power events? - Super User
' http://superuser.com/questions/121045/is-there-a-way-to-execute-a-program-on-power-events

' The two lines beginning CreateObject("WScript.Shell").Run ... do the Registry changes
 ' - The change to the TitleBar colour of the active window happens within a second
 ' - I would normally add the arguments , 0 or , 7 to make the cmds run hidden or minimised but, in this case, doing so stops the TitleBar colour of the active window changing until the next time any window is switched
 ' - as a result of both those arguments being omitted, there is a brief flash onscreen as the cmd window opens & closes

' Since sometime in September 2020, Windows defender has started detecting this script as a Trojan so I have had to Restore then Allow it.
' - I have since added its folder as a WD Exclusion
' - During this period, WD has also started reporting false positives on several of my innocuous vba & command scripts

Dim battery_status, prev_status
prev_status = CheckBattery
Set colMonitoredEvents = GetObject("winmgmts:\\.\root\cimv2")._
ExecNotificationQuery("Select * from Win32_PowerManagementEvent")
Do
    Set strLatestEvent = colMonitoredEvents.NextEvent
    If strLatestEvent.EventType = 10 Then
        battery_status = CheckBattery
        If battery_status <> prev_status Then
            If battery_status = 1 Then
                ' Action to take upon changing to battery power
               ' - Orange
                CreateObject("WScript.Shell").Run "cmd.exe /C reg add HKCU\Software\Microsoft\Windows\DWM /v ""AccentColor"" /t REG_DWORD /d 4278237695 /f "
            ElseIf battery_status = 2 Then
                ' Action to take upon changing to AC power
                ' - Dark green
                CreateObject("WScript.Shell").Run "cmd.exe /C reg add HKCU\Software\Microsoft\Windows\DWM /v ""AccentColor"" /t REG_DWORD /d 4282288400 /f "
            End If
        End If
    End If
    prev_status = battery_status
Loop

Function CheckBattery
    Dim oWMI, items, item
    Set oWMI = GetObject("winmgmts:\\.\root\cimv2")
    Set items = oWMI.ExecQuery("Select * from Win32_Battery",,48)
    For Each item in items
        If item.BatteryStatus = 1 Then
            CheckBattery = 1
            Exit Function
        ElseIf item.BatteryStatus = 2 then
            CheckBattery = 2
            Exit Function
        End If
    Next
End Function

Denis