Help Creating "Drag & Drop" .bat file to Append File Names

I have been attempting to come up with a way to be able to drag and drop a file to append 3 letters to it. The issue is that the extent of my programming knowledge lies in VBA and not much else. While I could probably make it work in VBA, I'd prefer to not require the application to be open when it's needed - which leads me to the usage of a .bat file.

The following are examples of what I was thinking of before and after file names. It would need to append ABC after the file name, but prior to the file extension.

test1.pdf ---> test1 ABC.pdf
test2 - substr.pdf ---> test2 - substr ABC.pdf
6.9.21 test3.pdf ---> 6.9.21 test3 ABC.pdf

This will be on my office PC, so my PC specs may be different than what's in my bio, although I have a feeling it wouldn't have made much of a difference either way.

Windows 10 Pro
Version 20H2
Build 19042.985

Thanks for any assistance and your time.

- - - Updated - - -

Some additional info. My thought was the .bat file would remain on my desktop. I would select 1 or more .pdf files from any folder or location and drag them and drop them into this file. The .bat file would go to work and automatically rename them by appending 'ABC' at the end of the file name (but before the ext).

I found some topics online that are similar to my issue, but I am not familiar enough with this particular process to modify to my needs.
Batch script, file drag&drop, change extension and reload file - Stack Overflow

Thanks Try3.

While I basically rewrote the code for the most part, you definitely lead me to the answer with what you provided. Thanks for your help!

Here's the result with comments:

Code:

Option Explicit

Dim FSO: Set FSO = CreateObject("Scripting.FileSystemObject")
Dim sInit: sInit = GetInitials

Dim FileCounter, ObjectInUse, OldName, NewName
For FileCounter = 0 to WScript.Arguments.Count-1

	Set ObjectInUse = fso.GetFile(WScript.Arguments.Item(FileCounter))
	
	OldName = ObjectInUse.Name
	
	'Use regex to get the file name (.*) and the file ext (\.[A-Z]{1,4})$
	'Then reconstruct the string with the file name .Item(0), the initials (with a space) " " & sInit, and the file ext .Item(1)
	With New RegExp
		.IgnoreCase = True
		.Pattern = "(.*)(\.[A-Z]{1,4})$"
		With .Execute(oldname)(0).SubMatches
			NewName = .Item(0) & " " & sInit & .item(1)
		End With
	End With
	
	'Use FSO to rename the file
	ObjectInUse.Name = NewName
	
Next

Function GetInitials

	'Get user's app folder to load/save initalials to
	Dim sAppData: sAppData = CreateObject("WScript.Shell").ExpandEnvironmentStrings("%AppData%")

	'Check if the file that stores the user's initials is saved. If so, read the file to be used as the return value for function.
	'Otherwise, create a new file and prompt the user for their initials and save to the new text file for later use.	
	With FSO
		If Not .FolderExists(sAppData & "\KeithMacros\") Then .CreateFolder sAppData & "\KeithMacros\"
		If Not .FileExists(sAppData & "\KeithMacros\SendToInitials.txt") Then 
			With .CreateTextFile(sAppData & "\KeithMacros\SendToInitials.txt")
				Do
					sInit = InputBox("This is your first time using this program. Please enter your initials", "Enter Initials")
				Loop until MsgBox("Are you sure you want to save the initials [" & sInit & "]?", vbYesNo, "Please Confirm") = vbYes
				.Write sInit
				.Close
			End With
		Else
			With .OpenTextFile(sAppData & "\KeithMacros\SendToInitials.txt")
				GetInitials = .ReadAll
				.Close
			End With
		End If
	End With
	
End Function